モナたんメモ

MOD情報

MOD名 CraftTweaker
作成者 Jaredlll08
配布場所 Curse Forge
前提MOD
バージョン 1.3.2, 1.7.10 - 1.12.2
サーバー側導入 〇
クライアント側導入 〇
FTB Wiki https://ftb.gamepedia.com/CraftTweaker
ソースコード https://github.com/CraftTweaker/CraftTweaker

MOD導入注意事項

  • 特になし

MOD概要

  • Minetweaker3の改善版
  • アイテムのレシピなどを変えられる。MODのアイテムにも一部対応
  • この解説は使いそうな物だけ載っています。詳しい説明はCraftTweaker Wiki及びMineTweaker Wiki参照。公式wikiを参考にしてこの解説は作っています

基本的な知識

  • Item Delocalizerを入れ、F3+Hでitemid等をNEI上で確認可能になる
  • コマンド /mt hand でitemid入手可能
  • /scripts/の中に.zsファイルを作り、スクリプトを書くことでレシピの変更が可能
  • zsファイルを編集し、コマンド/mt reloadを使うことで逐次確認できる
  • サーバー側に同じscriptを置くこと
  • ModTweakerを導入すると、ModTweaker対応MODのクラフト方法が使える
  • Modpackの難易度変更によるレシピの変化の実装はFTB Tweaksで行う

追加コマンド

    /minetweakerは/mtとしても可能
  • /minetweaker biomes
    • 全バイオームリストを出力
  • /minetweaker blockinfo
    • 実行後、ブロック右クリックすることでIDやmeta値等の情報入手
  • /minetweaker blocks
    • 全ブロックリストを出力
  • /minetweaker botania
    • Botaniaの全レシピリストを出力
  • /minetweaker botaniaBrews
    • BotaniaのBotanical Breweryのキーリストを出力
  • /minetweaker botaniaOrechid
    • Orechidで生成される鉱石の確率リストを出力
  • /minetweaker entities
    • Entity一覧リストを出力
  • /minetweaker hand
    • 手に持っているアイテムidを出力
  • /minetweaker inventory
    • インベントリ内のアイテムidを出力
  • /minetweaker lexiconCategories
    • Thaumcraft4のカテゴリー一覧を出力
  • /minetweaker lexiconKnowledgeTypes
  • /minetweaker lexiconPages
  • /minetweaker lexiconPages ページ名
  • /minetweaker liquids
    • 液体一覧を出力
  • /minetweaker seeds
    • 草から出る種一覧を出力?
  • /minetweaker mfr fertilizers
  • /minetweaker mfr fruits
  • /minetweaker mfr laserores
  • /minetweaker mfr rubbertreebiomes
  • /minetweaker mfr sludgedrops
  • /minetweaker mods
    • modid - mod名 - version一覧を出力
  • /minetweaker name アイテムid
    • modidよりそのmodのアイテム一覧を出力?
  • /minetweaker names
    • 全アイテムidとアイテム名一覧を出力
  • /minetweaker oredict
    • 全鉱石辞書を出力
  • /minetweaker oredict 辞書キー
    • 辞書キーのアイテムを出力?
  • /minetweaker recipes
    • 全レシピリストを出力?
  • /minetweaker recipes hand
    • 手に持っている物のレシピを出力
  • /minetweaker recipes furnace
    • かまどレシピリストを出力
  • /minetweaker reload
    • スクリプトの再読み込み、実行
  • /minetweaker tooltips
    • ツールチップの付与？
  • /minetweaker loot
    • ルート場所のキーと、入っているアイテムとその確率を出力
  • /minetweaker seed
    • 草を壊した時の出てくるアイテムとその確率を出力

基本構文

コメントアウト

    // 1行コメントアウト
					
/*
複数行コメントアウト
*/

ログ出力

  • ./minetweaker.logにコメントを出力
  • エラーが出たときにどのログの前でエラーを吐いたかわかる
    • // ログ出力
print("ログです");

アイテム・液体等の取得

    /*
アイテムの取得 鉄インゴット
<modid:itemid>
/mt hand やNEI等でitemid入手可能
*/
<minecraft:iron_ingot>

/*
鉱石辞書の取得鉄インゴット
<ore:orename>
/minetweaker oredict でorename取得可能
*/
<ore:ingotIron>

/*
Entityの取得
<entity:modID:entityName>
/minetweaker entities でmodID:entityNameを取得可能
*/
<entity:minecraft:sheep>

/*
液体の取得
<liquid:liquidname>
/mt liquids でliquidname取得可能
*/
<liquid:liquidname>

/*
ポーションの取得
<potion:modname:potionname>
*/
<potion:minecraft:strength>

変数定義

    //後から変更不可
val iron = <minecraft:iron_ingot>;

//後から変更可能
var iron2 = <minecraft:iron_ingot>;

表示名変更

    //https://www.kwonline.org/u_esc_seq.php のエスケープで日本語表示可能
//Ex.1)「鉄インゴット」の表示名を「鉄ingot」に;
<minecraft:iron_ingot>.displayName = "\u9244ingot";

//Ex.2)「鉄インゴット」の表示名を「鉄インゴットです」に;
<minecraft:iron_ingot>.displayName += "\u3067\u3059";

配列の使用

    //Ex)　配列内のアイテムの表示名を全て変える;
//外部のclassを読み込み
import minetweaker.item.IItemStack;

/*
IItemStackの配列([]で配列化)、変数名 array を定義
val array = ["a", "b", "c"]とすると、array[0] = a, array[1] = b, array[2] = c 
*/
val array = [<minecraft:iron_ingot>,<minecraft:emerald>] as IItemStack[];

/*
item に arrayの1番目,2番目...を代入していく、arrayの長さ分のループ文
*/
for item in array {
	//アイテム表示名を Changed! に
    item.displayName = "Changed!";
}

/*
item に arrayの1番目,2番目...を代入していく、arrayの長さ分のループ文
1番目のループはi=0, 2番目のループはi=1...となる
また、この式は上のループ文と同じ結果となる
*/
for i, item in array {
	//配列i番目のアイテム表示名を Changed! に
    array[i].displayName = "Changed!";
}

/*
以上の配列はi番目として定義、取得していたが、以下の方法で文字でも取得可能である
*/
val array2 = {
    iron : <minecraft:iron_ingot>,
    eme : <minecraft:emerald>
} as IItemStack[string];

/*
配列のironで定義されたアイテム表示名を Changed! に
<minecraft:iron_ingot>.displayName = "Changed!"; と同じ役割
*/
array2["iron"].displayName = "Changed!";

関数の使用

    // 関数 changeName　用import
import minetweaker.item.IItemStack;

//関数名　changeIronName を実行
changeIronName();

//関数1
function changeIronName(){
	<minecraft:iron_ingot>.displayName = "Changed!";
}

//定義
val iron = <minecraft:iron_ingot>;
val apple = <minecraft:apple>;

//関数名 changeName に中の値を渡して実行
changeName(iron);
changeName(apple);

//関数2 この場合、受け取る値は IItemStack　であること
function changeName(name as IItemStack){
    name.displayName = "Changed!";
}

//配列でも可能
val array = [<minecraft:iron_ingot>, <minecraft:apple>] as IItemStack[];
changeNameArray(array);

//配列を受け取る関数
function changeNameArray(names as IItemStack[]){
	for name in names{
		name.displayName = "Changed!";
	}
}

クラフトレシピの追加

    // 定形レシピの追加
/* ウィザスケの頭のレシピ
ソウルサンド |             |  ソウルサンド
ソウルサンド | スケルトンの頭 |  ソウルサンド
ソウルサンド |             |  ソウルサンド
*/
recipes.addShaped(<minecraft:skull:1>,
 [[<minecraft:soul_sand>, null, <minecraft:soul_sand>],
  [<minecraft:soul_sand>, <minecraft:skull>, <minecraft:soul_sand>],
  [<minecraft:soul_sand>, null, <minecraft:soul_sand>]]);

// 不定形レシピの追加
/*
鉱石辞書plankWood, ソウルサンド*3個よりウィザスケの頭4個作成
*/
val soul = <minecraft:soul_sand>;
recipes.addShapeless(<minecraft:skull:1> * 4, [<ore:plankWood>, soul, soul, soul]);

//配列を使ったレシピ追加例
/* オレンジ羊毛レシピ
羊毛 | 羊毛        | 羊毛
羊毛 | オレンジ染料 | 羊毛
羊毛 | 羊毛        | 羊毛
*/
import minetweaker.item.IItemStack;

val orangeWool = <minecraft:wool:1>;
val orangeDye = <minecraft:dye:14>;

addWoolColorRecipe(orangeWool, orangeDye);

function addWoolColorRecipe(product as IItemStack, dye as IItemStack){
	val wool = <minecraft:wool>;
	recipes.addShaped(product,
	 [[wool, wool, wool],
	  [wool, dye, wool],
	  [wool, wool, wool]]);
}

クラフトレシピの削除

    //棒のすべての定形クラフトレシピ削除
recipes.removeShaped(<minecraft:stick>);

//オークの木を使った棒の定形クラフトレシピのみ削除
recipes.removeShaped(<minecraft:stick>, 
[[<minecraft:planks>],
[<minecraft:planks>]]);

//鉱石辞書 plamlWood の不定形レシピのみ削除
recipes.removeShapeless(<ore:plankWood>);

レシピの変更

    /*
木から棒4本とか甘えだよなあ？
レシピ削除→レシピ追加　でレシピ変更
*/

//木を2つ使った棒の定形クラフトレシピのみ削除
recipes.removeShaped(<minecraft:stick>, 
[[<ore:plankWood>],
[<ore:plankWood>]]);

//木2つで棒2本の不定形レシピ追加
recipes.addShaped(<minecraft:stick> * 2,
[<ore:plankWood>,
<ore:plankWood>]);

鉱石辞書関係

    //石炭の鉱石辞書に plankWood を追加
val oredict = <ore:plankWood>;
oredict.add(<minecraft:coal>);

//dyeの鉱石辞書を持つアイテムに鉱石辞書 plankWood を追加
val wooddict = <ore:plankWood>;
val dyedict = <ore:dye>;
oredict.addAll(dyedict);

//鉱石辞書 plankWood を持つアイテムの表示名を"Changed!"に
for item in <ore:plankWood>.items {
    item.displayName = "Changed!";
}

かまどレシピ関係

    //かまどレシピ追加 鉄インゴット*9→鉄ブロック
furnace.addRecipe(<minecraft:iron_block> , <minecraft:iron_ingot>);

//かまどレシピ追加 鉄インゴット*9→鉄ブロック 経験値5.0
furnace.addRecipe(<minecraft:iron_block> , <minecraft:iron_ingot>, 5.0);

//鉄インゴットの全かまどレシピ削除
furnace.remove(<minecraft:iron_ingot>);

//鉄インゴットの鉄鉱石を使うかまどレシピのみ削除
furnace.remove(<minecraft:iron_ore>, <minecraft:iron_ingot>);

//燃料となるアイテム追加 ネザースター 10000tick(500秒)
furnace.setFuel(<minecraft:nether_star>, 10000);

NBTタグ関係

    //10ダメージ受けた石ピッケル
val pick1 = <minecraft:stone_pickaxe>;
val damagedPick = pick1.withDamage(10);
recipes.addShaped(damagedPick, [[pick1, pick1]]);

//5ダメージ受けた、表示名がChangedで、説明にChanged by CraftTweaker(改行)There is 5 damageを追加された鉄ピッケル
val pick2 = <minecraft:iron_pickaxe>;
val damagedPick2 = pick2.withDamage(5).withTag({display: {Name: "Changed!", Lore: ["Changed by CraftTweaker", "There is 5 damage"]}});
recipes.addShaped(damagedPick2, [[pick2, pick2]]);

//ダメージを食らっているもののみ
val damagedpick = pick2.onlyDamaged();

//少なくとも15ダメージ以上食らっているもののみ
val damagedleastpick = pick2.onlyDamageAtLeast(15);

//100ダメージ未満のもののみ
val damagedmostpick = pick2.onlyDamageAtMost(100);

//15-100ダメージのもののみ
val damagedbetweenpick = pick2.onlyDamageBetween(15, 100);

/*
修復レシピの例文
*/
import minetweaker.item.IItemStack;

//ダメージ受けた鉄ピッケルを鉄インゴットで直せるレシピ　その1
/*
	*はワイルドカード、どんな数字でも入る意味
*/
val pick3 = <minecraft:iron_pickaxe:*>;
recipes.addShaped(<minecraft:iron_pickaxe>, [[pick3, <minecraft:iron_ingot>]]);

//ダメージ受けた鉄ピッケルを鉄インゴットで直せるレシピ　その2
//石ピッケルの耐久16だよね？(Greg脳
val pick4 = <minecraft:stone_pickaxe>;
val repair = <minecraft:cobblestone>;
repairTool(pick4, repair);

function repairTool(pick as IItemStack, material as IItemStack){
	var meta = [1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15] as int[];
	for i in meta{
		recipes.addShaped(pick, [[pick.withDamage(i), material]]);
	}
}

//ダメージ受けた石ピッケルを丸石で25ダメージ分直せるレシピ
/*
markedはスクリプト内の名前を付けている

function内の引数は、
<minecraft:stone_pickaxe>　がoutput
<minecraft:stone_pickaxe>.anyDamage().marked("pick")　がinput
<minecraft:cobblestone> がcrafting　を表している

returnは値を返している

max(0, inputs.pick.damage - 25) は、 25引いたときにダメージ値が負の数にならないようにするためである
*/
recipes.addShapeless(<minecraft:stone_pickaxe>,
[<minecraft:stone_pickaxe>.anyDamage().marked("pick"), <minecraft:cobblestone>],
	function(output, inputs, crafting) {
		return inputs.pick.withDamage(max(0, inputs.pick.damage - 25));
	}
);

ツールチップ関係

    //鉱石辞書 plankWood のアイテムのツールチップに　This is wood を追加
<ore:plankWood>.addTooltip("This is wood");

//棒のshiftを押したときに表示されるツールチップ shift-click
<minecraft:stick>.addShiftTooltip("shift-click");

/*
文字の色
format.black
format.darkBlue
format.darkGreen
format.darkAqua
format.darkRed
format.darkPurple
format.gold
format.gray
format.darkGray
format.blue
format.green
format.aqua
format.red
format.lightPurple
format.yellow
format.white

文字の字形
format.obfuscated　　難読化
format.bold　　太字
format.strikethrough　　打消し線
format.underline　　下線
format.italic　　傾斜

https://www.kwonline.org/u_esc_seq.php のエスケープで日本語表示可能
*/

//Italic and strikethrough red
<minecraft:stick>.addTooltip(format.green(format.italic("Italic") + " and " + format.strikethrough("strikethrough")) + format.red(" red"));

チェストルート品関係

    /*
ダンジョンチェストにエンダーチェストを確率50で追加
/mt lootよりダンジョンキーの取得可能
*/
vanilla.loot.addChestLoot("dungeonChest", <minecraft:ender_chest>.weight(100));

/*
ダンジョンチェストにエンパを確率100で1-10個追加
/mt lootよりダンジョンキーの取得可能
*/
vanilla.loot.addChestLoot("dungeonChest", <minecraft:ender_pearl>.weight(100), 1, 10);

/*
廃坑チェストよりエンチャント本を削除
/mt lootよりダンジョンキーの取得可能
*/
vanilla.loot.removeChestLoot("mineshaftCorridor", <enchanted_book>);

/*
廃坑チェストのアイテム全削除
/mt lootよりダンジョンキーの取得可能
*/
vanilla.loot.removeChestLoot("mineshaftCorridor", <*>);

草ルート品関係

    /*
草破壊時にエンダーパールを確率100でドロップ
/mt seedよりドロップ一覧と確率を表示
*/
vanilla.seeds.addSeed(<minecraft:ender_pearl>.weight(100));

/*
草破壊時に種を落とさないようになる
/mt seedよりドロップ一覧と確率を表示
*/
vanilla.seeds.removeSeed(<minecraft:wheat_seeds>);

言語翻訳関係

    /*
英語の時のみ表示名を変える
NEIの nei.inventory.prev(Prevボタン) の部分の翻訳を Past に変更
*/
game.setLocalization("en_US", "nei.inventory.prev", "Past");

/*
全言語にて表示名を変える
NEIの nei.inventory.next(Nextボタン) の部分の翻訳を 次へ に変更
https://www.kwonline.org/u_esc_seq.php のエスケープで日本語表示可能
*/
game.setLocalization("nei.inventory.next", "\u6b21\u3078");

MOD連携

Modpack難易度変更によるレシピ変更(FTB Tweaks)

  • FTB Tweaksを導入することで可能
  • /ftb_mode set (難易度キー) のコマンドで難易度変更が可能
  • ./modpack/(難易度キー)/scripts/-.zs にスクリプトを置く
  • ./modpack/gamemodes.json に難易度キーを追加することで変更可能に
  • defaultは初期モード設定、commonはモード関係なく共通なスクリプトを置く
  • 以下normalモードとexpertモードの例、初期モードはnormal
    • {
  "modes": [
    "normal",
    "expert"
  ],
  "default": "normal",
  "common": "common"
}

アイテムの取得

    /*
全く同じ
<modid:itemid>
/mt hand やNEI等でitemid入手可能
*/
//Botaniaのマナスティール
<Botania:manaResource>

Better Storage連携

    //経験値の引数は無くても可(0経験値)

/*
CraftingStationに5経験値で金ブロックからチェストを作る不定形レシピ追加
*/
mods.betterstorage.CraftingStation.addShapeless([<minecraft:gold_block>],[<minecraft:chest>], 5.0);

/*
CraftingStationに10経験値でチェーンのチェストプレートとBotaniaのマナスティールを作る定形レシピ追加
*/
mods.betterstorage.CraftingStation.addShaped([<minecraft:chainmail_chestplate>, <Botania:manaResource>],
[[<minecraft:iron_ingot>, null, <minecraft:iron_ingot>],
 [<minecraft:string>, <minecraft:iron_ingot>, <minecraft:string>],
 [<minecraft:iron_ingot>, <minecraft:string>, <minecraft:iron_ingot>]],
 10.0);

Blood Magic連携

    /*
Blood Altarの祭壇クラフト　レシピ追加
引数は 搬入アイテム, 生成アイテム, 祭壇Tier, 必要LP, クラフト中使用LP, 血不足時の吸収LP(祭壇に血が無いときクラフトに使ったLPが消えていく)
*/
//グロウストーンダストからレッドストーンを作成、祭壇Tier3、5000LP必要、20LP消費し続ける、20LPが吸収される
mods.bloodmagic.Altar.addRecipe(<minecraft:glowstone_dust>, <minecraft:redstone>, 3, 5000, 20, 20);

/*
Blood Altarの祭壇クラフト レシピ削除
Blood MagicのBlank Slateのレシピ削除
*/
mods.bloodmagic.Altar.removeRecipe(<AWWayofTime:blankSlate>);


/*
エンパの定形クラフトレシピを追加する
クラフト時にBlood Orbを消費しないで残る
*/
mods.bloodmagic.BloodOrb.addShaped(<minecraft:ender_pearl>,
[[<AWWayofTime:weakBloodShard>, <AWWayofTime:crystallos>,<AWWayofTime:weakBloodShard>], [<AWWayofTime:magicales>, <AWWayofTime:magicianBloodOrb>, <AWWayofTime:magicales>], [<AWWayofTime:weakBloodShard>, <AWWayofTime:crystallos>, <AWWayofTime:weakBloodShard>]]);

/*
Demon Blood Shardの不定形クラフトレシピを追加する
クラフト時にBlood Orbを消費しないで残る
*/
mods.bloodmagic.BloodOrb.addShapeless(<AWWayofTime:demonBloodShard> * 5, 
[<AWWayofTime:archmageBloodOrb>, <AWWayofTime:demonBloodShard>, <AWWayofTime:bloodMagicBaseItems:27>]);

/*
粘土2個を作るAlchemy Chemistry Setのレシピを追加する
生成物, [素材1, 素材2, 素材3 ... 素材5までの配列], オーブのTier, 必要LP

オーブTier
Tier1 : Weak Blood Orb
Tier2 : Apprentice...
Tier3 : Magician's...
Tier4 : Master...
Tier5 : Archmage's...
Tier6 : Transcendent...
*/
mods.bloodmagic.Alchemy.addRecipe(<minecraft:clay> * 2,
[<minecraft:hardened_clay>, <minecraft:hardened_clay>, <minecraft:water_bucket>], 1, 100);

/*
氷を作るAlchemy Chemistry Setのレシピを削除する
*/
mods.bloodmagic.Alchemy.removeRecipe(<minecraft:ice>);

/*
石炭から岩盤を作るRitual of Bindingのレシピ追加
*/
mods.bloodmagic.Binding.addRecipe(<minecraft:coal_block>, <minecraft:bedrock>);

/*
Bound Bladeを作るRitual of Bindingのレシピ削除
*/
mods.bloodmagic.Binding.removeRecipe(<AWWayofTime:energySword>);

/***
儀式 Mark of the Falling Tower にて落ちる隕石の変更

引数は 儀式のときに上に投げるアイテム, 隕石の半径, "構成ブロック1, 構成ブロック1の確率, 構成ブロック2...(ry"

確率の最大値は、./config/AWWayofTime.cfg の meteor > I:maxChance の値(デフォルト 1000)
落ちるブロックの確率を全て足し、残りは石が割り当てられる

バグ？で鉱石辞書の一番最初しか反映されないので、落としたいやつごとに新しい鉱石辞書を作り設定する
***/
//ネザーラックの鉱石辞書 netherBlocks 付与
val netherBlocks = <ore:netherBlocks>;
netherBlocks.add(<minecraft:netherrack>); 

//ソウルサンドの鉱石辞書 soul 付与
val oresoul = <ore:soul>;
oresoul.add(<minecraft:soul_sand>);

//グロウストーンの鉱石辞書 glow 付与
val glow = <ore:glow>;
glow.add(<minecraft:glowstone>);

/*
Deamon Portalを投げ儀式、
半径10ブロック、
鉱石辞書 netherBlocks(確率200)、
鉱石辞書 soul(確率300)、
鉱石辞書 soul(確率500)
*/
mods.bloodmagic.FallingTower.addFocus(<AWWayofTime:demonPortalMain>,
10,
"netherBlocks, 200,
soul, 300,
glow, 500");

//儀式 Mark of the Falling Tower の上に投げるアイテムごとに儀式削除
//ネザースターを投げる儀式の削除
mods.bloodmagic.FallingTower.removeFocus(<minecraft:nether_star>);

/*
儀式 Reap of the Harvest Moon に対応する種の追加

成長した時のブロック情報, 種のアイテムid

作物は成長段階でmeta値が変わる(例: BiomesOPlentyのチューリップはmeta値7で作物ができる)ので、 /mt blockinfo で右クリをして満開時のmeta値を調べる
*/
//BiomesOPlentyのチューリップ(満開時meta値7)を儀式に対応
mods.bloodmagic.HarvestMoon.addHarvestable(<BiomesOPlenty:turnip:7>, <BiomesOPlenty:turnipSeeds>);

Buildcraft 連携

  • Buildcraft Compatの導入必須
    • /*
Assembly Tableのレシピ追加

引数は 生成物, 必要RF, 搬入物配列 
*/
// 砂利 + 丸石2 + ガラス + 5000RF → BuidcraftのPipe Plug　のレシピ追加
mods.buildcraft.AssemblyTable.addRecipe(<BuildCraft|Transport:pipePlug>,
5000,
[<minecraft:gravel>, <minecraft:cobblestone> * 2, <minecraft:glass>]);

/*
Assembly Tableのレシピ追加

引数は 生成物, 搬入物配列, ワイルドカード(*)を使用しているか(true/false)
*/
//レッドストーン から BuidcraftのRedstone Chipsetを作るレシピの削除　*は使っていないためfalse
mods.buildcraft.AssemblyTable.removeRecipe(<BuildCraft|Silicon:redstoneChipset>, [<minecraft:redstone>], false);

/*
鉄製のCombustionEngineに燃料を追加

引数は 燃料の液体名, RF/1サイクル, 燃焼時間
*/
//CombustionEngineにマグマ燃料を追加、1サイクル5000RF生成、200tick燃える
mods.buildcraft.Fuels.addCombustionEngineFuel(<liquid:lava>, 5000, 200);

/*
鉄製のCombustionEngineの燃料を削除

引数は 燃料の液体名
*/
//Buildcraftのfuelを燃料としない
mods.buildcraft.Fuels.removeCombustionEngineFuel(<liquid:fuel>);

/*
鉄製のCombustionEngineの冷却材を追加

引数は 燃料の液体名, 生成量(mB)
*/
//oilを燃料として追加、100mB分
mods.buildcraft.Fuels.addCombustionEngineCoolant(<liquid:oil>, 100);

/*
鉄製のCombustionEngineの冷却材を削除

引数は 燃料の液体名
*/
//水を冷却材としない
mods.buildcraft.Fuels.removeCombustionEngineCoolant(<liquid:water>);

/*
Refineryのレシピ追加

引数は 生成液体名, RF/mB, mB/tick, 搬入液体名1, 搬入液体名2
*/
//oil 2mB生成、25RF/mb必要、25mB/tick必要、水と溶岩より生成
mods.buildcraft.Refinery.addRecipe(<liquid:oil> * 2, 25, 25, <liquid:water>, <liquid:lava>);

/*
Refineryのレシピ削除

引数は 液体名
*/
//fuelを作るレシピ削除
mods.buildcraft.Refinery.removeRecipe(<liquid:fuel>);

/*
Programming Tableのレシピ追加

引数は 搬入物, 必要RF, 生成物配列, 1回限りのクラフトか(true/false)
*/
//水バケツをProgramming Tableに搬入、氷か氷塊を選びクラフト、5000RF必要、再度のクラフト不可
mods.buildcraft.ProgrammingTable.addRecipe(<minecraft:water_bucket>, 5000, [<minecraft:ice>, <minecraft:packed_ice>], true);

/*
公式wikiにこのコードがあるが何故か動かないので注意?
//InputStack, OutputFluid
//mods.buildcraft.Fuels.addCoolantItem(<minecraft:ice>, <liquid:water> * 1000);

//InputStack, OutputFluid, Multiplier
mods.buildcraft.Fuels.addCoolantItemWithMultiplier(<minecraft:packed_ice>, <liquid:water> * 4000, 2);

//InputStack
mods.buildcraft.Fuels.removeCoolantItem(<minecraft:water_bucket>);
*/

Gregtech5U 連携

  • GTTweakerの導入必須
  • /mt reloadをしてもstack errorでNEIにも表示されないが再起動すると直る
  • 消費電力変えられない所は、GTNH版のGregtech/GTNewHorizonCoreModのソースコードをいじると可能？
    • //クラフト時間(tick) × エネルギー量/tick = 全必要エネルギー量

/*
Alloy Smelterのレシピ追加

引数は　生成物, 搬入物1, 搬入物2, クラフト時間(tick), エネルギー量/tick
*/
//スライムボール3つ作るレシピ、IC2のRubberとGT5UのMold(Ball)、30EU/t, クラフト時間800tick, 計24000EU
mods.gregtech.AlloySmelter.addRecipe(<minecraft:slime_ball>*3, <IC2:itemRubber>, <gregtech:gt.metaitem.01:32307>, 800, 30);

/*
UU Amplifabricatorのレシピ追加

引数は　搬入物1, クラフト時間(tick), UU Amplifier生成量
*/
//TNTから10 UU Amplifierを作るレシピ、32EU/t、200tick、全6400EU
mods.gregtech.Amplifabricator.addRecipe(<minecraft:tnt>, 200, 10);

/*
Arc Furnaceレシピ追加

引数は　生成物配列, 搬入物, 搬入液体, 生成物生成確立配列(÷100したものが%), クラフト時間(tick), エネルギー量/tick
*/
//Wrought Iron Ingot 5個(100%)とWrought Iron Ingot 4個(50%)生成、IC2のShaft(Iron)とLiquid Oxygen 504Lを素材、1200tick、32EU/t、計38400EU
mods.gregtech.ArcFurnace.addRecipe([<gregtech:gt.metaitem.01:11304> * 5, <gregtech:gt.metaitem.01:11304> * 4], <IC2:itemRecipePart:11>, <liquid:oxygen> * 504, [10000, 5000], 1200, 32);

/*
Assemblerレシピ追加

引数は　生成物, 搬入物配列, 搬入液体, クラフト時間(tick), エネルギー量/tick
*/
//IC2のRTG　Pellets作成、素材は木6個とエンダーチェスト1個とネザースター3個とglue 1000L、1200tick、128EU/tick、計153600EU
mods.gregtech.Assembler.addRecipe(<IC2:itemRTGPellet>,
[<minecraft:planks> * 6, <minecraft:ender_chest> * 1, <minecraft:nether_star> * 3], <liquid:glue> * 1000, 1200, 128);

/*
Assembling Lineレシピ追加

引数は　スキャンアイテム, スキャン時間(tick), 搬入物配列(=>4つ), 搬入液体配列, 生成物, クラフト時間(tick), エネルギー量/tick
*/
//エンダーチェストをScannerで2000tickかけてData Stick作成、木6個と土とネザースター3個と原木3個と水1000Lと溶岩2000Lで砂を作る、1200tick、128EU/
mods.gregtech.AssemblyLine.addRecipe(<minecraft:ender_chest>, 2000,
[<minecraft:planks> * 6, <minecraft:dirt> * 1, <minecraft:nether_star> * 3, <minecraft:log> * 3],
[<liquid:water> * 1000, <liquid:lava> * 2000],
<minecraft:sand>, 1200, 128);

/*
Autoclaveレシピ追加

引数は　生成物, 搬入物, 搬入液体, 生成物生成確立配列(÷100したものが%), クラフト時間(tick), エネルギー量/tick
*/
//Diamond Dustと水200Lからダイアモンド(90%)生成, 32EU/t, 2000tick, 全64000EU
 mods.gregtech.Autoclave.addRecipe(<minecraft:diamond>, <gregtech:gt.metaitem.01:2500>, <liquid:water> * 200,
 9000, 2000, 32);

/*
Blast Furnaceレシピ追加

引数は　生成物配列, 搬入液体, 搬入物配列, クラフト時間(tick), エネルギー量/tick, 温度
*/
//Diamond DustとエンダーチェストとLiquid Oxygen 9000Lからダイアモンドとオークの木を生成、2000K、1500tick、120EU/tick、計180000EU
mods.gregtech.BlastFurnace.addRecipe([<minecraft:diamond>,<minecraft:planks>], 
<liquid:oxygen> * 9000,
[<gregtech:gt.metaitem.01:2500>, <minecraft:ender_chest>],
1500, 120, 2000);

/*
Breweryレシピ追加

引数は　生成液体、搬入物, 搬入液体, 隠す?(true/false)
消費電力は変更不可？
*/
//ネザースターとHolywaterからDistilled Water作成, 4EU/tick, 全512EU
mods.gregtech.Brewery.addRecipe(<liquid:ic2distilledwater> * 10000, <minecraft:nether_star>, <liquid:holywater> * 1000, false);

/*
Canning Machineレシピ追加

引数は　生成物配列、搬入物1, 搬入物2, クラフト時間(tick), エネルギー量/tick
*/
//サトウキビ4個とTin Canから(Filled) Tin Can4個と砂糖1個を作る、200EU/t、50tick、計10000EU
mods.gregtech.Canner.addRecipe([<IC2:itemTinCanFilled> * 4, <minecraft:sugar>], <minecraft:reeds> * 4, <IC2:itemTinCan>, 50, 200);

/*
Centrifugeレシピ追加

引数は　生成物配列、搬入液体, 搬入物1, 搬入物2, 生成液体, 生成物生成確立配列(÷100したものが%), クラフト時間(tick), エネルギー量/tick
*/
//Industrial TNT4個とWire Cutterと水200mBから、砂12個(100%), 火薬(90%), 火打石(80%), Mineral Water 200mBを生成、100tick, 50EU/tick, 計5000EU
mods.gregtech.Centrifuge.addRecipe([<minecraft:sand> * 12, <minecraft:gunpowder> * 15, <minecraft:flint> * 6],
<liquid:water> * 200,
<IC2:blockITNT> * 4, <gregtech:gt.metatool.01:26>,
<liquid:potion.mineralwater> * 200,
[10000, 9000, 8000],
100, 50);

/*
Chemical Bathレシピ追加

引数は　生成物配列, 搬入物, 搬入液体, 生成物生成確立配列(÷100したものが%), クラフト時間(tick), エネルギー量/tick
*/
//PainterとWater Mixed Black Dye144mBからBlack Painter作成、2EU/t, 200tick, 計400EU
mods.gregtech.ChemicalBath.addRecipe([<IC2:itemToolPainterBlack>], <IC2:itemToolPainter>, <liquid:dye.watermixed.dyeblack> * 144, [10000], 200, 2);

/*
Chemical Reactorレシピ追加

引数は　生成物1, (生成物2,) 生成液体, 搬入物1, 搬入物2, 搬入液体, クラフト時間(tick), エネルギー量/tick
*/
//骨粉とAshesとWater 1mBから、FertilizerとMineral Waterを作る、200tick, 120EU/tick, 計24000EU
mods.gregtech.ChemicalReactor.addRecipe(<IC2:itemFertilizer> * 2, null, <liquid:potion.mineralwater>,
<minecraft:dye:15>, <gregtech:gt.metaitem.01:2815>, <liquid:water>,
200, 120);

/*
Circuit Assemblerレシピ追加

引数は　生成物, 搬入物配列, 搬入液体, クラフト時間(tick), エネルギー量/tick
*/
//Good Electronic Circuit10個とElectronic Circuit5個と水1mBから、Wetware Mainframeを作る、200tick, 120EU/tick, 計24000EU
mods.gregtech.CircuitAssembler.addRecipe(<gregtech:gt.metaitem.03:32095>,
[<gregtech:gt.metaitem.01:32702> * 10, <IC2:itemPartCircuit> * 5],
<liquid:water>,
200, 120);

/*
Compressorレシピ追加

引数は　生成物, 搬入物, クラフト時間(tick), エネルギー量/tick
*/
//かまどから石64個を作る、200tick, 120EU/tick, 計24000EU
mods.gregtech.Compressor.addRecipe(<minecraft:stone> * 64,
<minecraft:lit_furnace>,
200, 120);

/*
Cutting Sawレシピ追加

引数は　生成物配列, 搬入物, 搬入液体, クラフト時間(tick), エネルギー量/tick
*/
//ベッドと水12mBから、木3個と羊毛3つを作る、30tick、30EU/tick、計900EU
mods.gregtech.CuttingSaw.addRecipe([<minecraft:planks> * 3, <minecraft:wool> * 3], <minecraft:bed>, <liquid:water> * 12, 30, 30);

/*
Distillation Towerレシピ追加

引数は　生成液体配列, 生成物, 搬入液体, クラフト時間(tick), エネルギー量/tick
*/
//Pahoehoe Lavaから、Volcanic Ashes 4個と溶岩 800mBとHeavy Oil 100mBとRaw Oil 75mBとLight Oil 25mBを生成、150tick, 100EU/tick, 5000EU
mods.gregtech.DistillationTower.addRecipe([<liquid:lava> * 800, <liquid:liquid_heavy_oil> * 100, <liquid:liquid_medium_oil> * 75, <liquid:liquid_light_oil> * 25],
<gregtech:gt.metaitem.01:2940> * 4,
<liquid:ic2pahoehoelava> * 1000, 50, 100);

/*
Distilleryレシピ追加

引数は　生成液体配列, 回路, 搬入液体, クラフト時間(tick), エネルギー量/tick, 隠す(true/false)

個数を*0にすることで消滅しない
*/
//Programmed Circuit ==4 とMilk 250mBからChocolate Milk 250mB作成、80tick, 30EU/tick, 計2400EU
mods.gregtech.Distillery.addRecipe(<liquid:potion.chocolatemilk> * 250,
<gregtech:gt.integrated_circuit:4> * 0,
<liquid:milk> * 250,
80, 30, false);

/*
Electrolyzerレシピ追加

引数は　生成物配列, 生成液体, 搬入物1, 搬入物2, クラフト時間(tick), エネルギー量/tick
*/
//Block of PlatinumとIridium Neutron ReflectorとMolten Platinum 1mBから、Gold Dust(100%), Small Pile of Gold Dust(80%), Tiny Pile of Gold Dust(60%), Molten Gold 1mBを生成、1000tick, 40000EU/tick, 計40000000EU
mods.gregtech.Electrolyzer.addRecipe([<gregtech:gt.metaitem.01:2086> * 3, <gregtech:gt.metaitem.01:1086> * 4, <gregtech:gt.metaitem.01:86> * 5],
<liquid:molten.gold>,
<gregtech:gt.blockmetal5:12>,
<gregtech:gt.neutronreflector>,
<liquid:molten.platinum>,
[10000, 8000, 6000],
1000, 40000);

/*
Extractorレシピ追加

引数は　生成物, 搬入物, クラフト時間(tick), エネルギー量/tick
*/
//オークの葉からオークの苗木を作成, 120tick, 128EU/tick, 計15360EU
mods.gregtech.Extractor.addRecipe(<minecraft:sapling>,
<minecraft:leaves>,
120, 128);

/*
Extruderレシピ追加

引数は　生成物, 搬入物1, 搬入物2, クラフト時間(tick), エネルギー量/tick

個数を*0にすることで消滅しない
*/
//ネザークオーツとExtruder Shape(Block)よりネザー水晶ブロックを作成, 120tick, 128EU/tick, 計15360EU
mods.gregtech.Extruder.addRecipe(<minecraft:quartz_block>,
<minecraft:quartz> * 4, <gregtech:gt.metaitem.01:32363> * 0,
120, 128);

/*
Fermenterレシピ追加

引数は　生成液体, 搬入液体, クラフト時間(tick), エネルギー量/tick, 隠す(true/false)
消費電力は変更不可？
*/
//溶岩1000mBからPahoehoe Lava50mB生成、20tick, 2EU/tick, 計40EU
mods.gregtech.Fermenter.addRecipe(<liquid:ic2pahoehoelava> * 50,
<liquid:lava> * 1000,
20, false);

/*
Fluid Cannerレシピ追加

引数は　生成物, 搬入物, 生成液体, 搬入液体
消費電力は変更不可？
*/
//Stone MugとDark Coffee500mBからDark CoffeeとSteam200mBを生成
mods.gregtech.FluidCanner.addRecipe(<IC2:itemMugCoffee:1>,
<IC2:itemMugEmpty>,
<liquid:steam> * 200,
<liquid:potion.darkcoffee> * 500);

/*
Fluid Extractorレシピ追加

引数は　生成物, 搬入物, 生成液体, 生成物生成確立(÷100したものが%), クラフト時間(tick), エネルギー量/tick
*/
//氷塊よりIce Cell(60%)とMolten Ice 4000mB生成、2EU/tick, 20tick, 40EU
mods.gregtech.FluidExtractor.addRecipe(<gregtech:gt.metaitem.01:30702>, <minecraft:packed_ice> , <liquid:ice> * 4000, 6000, 20, 2);

/*
Fluid Heaterレシピ追加

引数は　生成液体, 回路, 搬入液体, クラフト時間(tick), エネルギー量/tick

個数を*0にすることで消滅しない
*/
//Programmed Circuit ==0とIC2 Coolant 250mBでIC2 Hot Coolant 250mBを生成, 40tick, 20EU/tick, 800EU
mods.gregtech.FluidHeater.addRecipe(<liquid:ic2hotcoolant> * 250, <gregtech:gt.integrated_circuit> * 0, <liquid:ic2coolant> * 250, 40, 20); 

/*
Fluid Solidifierレシピ追加

引数は　生成物, Mold, 搬入液体, クラフト時間(tick), エネルギー量/tick

個数を*0にすることで消滅しない
*/
//Molten Ice 4000mBとMold(Block)よりPacked Iceを作成, 480tick, 64EU/tick, 計30720EU
mods.gregtech.FluidSolidifier.addRecipe(<minecraft:packed_ice>,
<gregtech:gt.metaitem.01:32308> * 0,
<liquid:ice> * 4000,
480, 64);

/*
Forge Hammerレシピ追加

引数は　生成物, 搬入物, クラフト時間(tick), エネルギー量/tick
*/
//Polyethylene Rod2本からLong Polyethylene Rodを作成, 20tick, 16EU/tick, 320EU
mods.gregtech.ForgeHammer.addRecipe(<gregtech:gt.metaitem.02:22874>, <gregtech:gt.metaitem.01:23874> * 2, 20, 16);

/*
Forming Pressレシピ追加

引数は　生成物, 搬入物1, 搬入物2, クラフト時間(tick), エネルギー量/tick
*/
//Reinforced GlassとMold(Arrow Head)よりEmpty Glass Arrow Head作成, 200tick, 480EU/tick, 計96000EU
mods.gregtech.FormingPress.addRecipe(<gregtech:gt.metaitem.01:32200> * 12, <IC2:blockAlloyGlass>, <gregtech:gt.metaitem.01:32316>
, 200, 480);

/*
Diesel Generator 燃焼物追加

引数は　生成物, 搬入物(1000mB扱い), 生成EU/mB
*/
//Heavy Oil Cellから1000LのHeavy Oilを入れ、IC2のEmpty Cellを搬出、250EU/tickで燃える
mods.gregtech.Fuels.addDieselFuel(<IC2:itemCellEmpty>, <gregtech:gt.metaitem.01:30730>,
250);

/*
Gas Turbine 燃焼物追加

引数は　生成物, 搬入物(1000mB扱い), 生成EU/mB
*/
//IC2のSteam Cellから1000LのSteamを入れ、IC2のEmpty Cellを搬出、100EU/tickで燃える
mods.gregtech.Fuels.addGasTurbineFuel(<IC2:itemCellEmpty>, <IC2:itemCellEmpty:14>,
100);

/*
Thermal Generator? 燃焼物追加

引数は　生成物, 搬入物(1000mB扱い), 生成EU/mB
*/
//こんな機械あったっけ？
mods.gregtech.Fuels.addThermalGeneratorFuel(<IC2:itemCellEmpty>, <IC2:itemCellEmpty:11>, 1000);

/*
Dense Fluid? 燃焼物追加

引数は　生成物, 搬入物(1000mB扱い), 生成EU/mB
*/
//こんな機械あったっけ？
mods.gregtech.Fuels.addDenseFluidFuel(<IC2:itemCellEmpty>, <gregtech:gt.metaitem.01:30964>, 2000);

/*
Large Plasma Generator 燃焼物追加

引数は　生成物, 搬入物(1000mB扱い), 全生成EU(×1000の値が全EU, EU/tickはタービン準拠)
*/
//IC2のSLava Cellから1000Lの溶岩を入れ、IC2のEmpty Cellを搬出、計20000EUで燃える
mods.gregtech.Fuels.addPlasmaGeneratorFuel(<IC2:itemCellEmpty>, <IC2:itemCellEmpty:2>,
20);

/*
Magic Energy Converter 燃焼物追加

引数は　生成物, 搬入物, 全生成EU(×1000の値が全EU, EU/tickはタービン準拠)
*/
//ドラゴンの卵からEnderpearl Lensを生成、計20000000EUで燃える
mods.gregtech.Fuels.addMagicGeneratorFuel(<gregtech:gt.metaitem.01:24532>, <minecraft:dragon_egg>,
20000);

/*
Fusion Recator 燃焼物追加

引数は　生成液体, 搬入液体1, 搬入液体2, クラフト時間(tick), エネルギー量/tick, 開始時消費電力
*/
//Molten Naquadah 50mBとMolten Plutonium 239 100mBからOld Man Snitches glitched Diablo Sauce 5mBを生成, 200tick, 5000EU/t, 計1000000EU, 開始時10000000EU消費
mods.gregtech.FusionReactor.addRecipe(<liquid:potion.diablosauce.strong> * 5, <liquid:molten.plutonium> * 100, <liquid:molten.naquadah> * 50, 200, 5000, 10000000); 

/*
Implosion Compressor レシピ追加

引数は　生成物配列, 搬入物, TNTの量(Industrial TNTはこの半分の量)
*/
//Quintuple Naquadria Plate32個とTNT32個(又はIndustrial TNT16個)から岩盤とDark Ashesを作成, 30EU, 20tick, 600EU
mods.gregtech.ImplosionCompressor.addRecipe([<minecraft:bedrock>, <gregtech:gt.metaitem.01:2816> * 16],
<gregtech:gt.metaitem.01:21327> * 32,
64);

/*
Lathe レシピ追加

引数は　生成物配列, 搬入物, クラフト時間(tick), エネルギー量/tick
*/
//レッドストーントーチから、レッドストーンと棒を生成, 640tick, 16EU/tick, 10240EU
mods.gregtech.Lathe.addRecipe([<minecraft:redstone>, <minecraft:stick>], <minecraft:redstone_torch>,
640, 16);

/*
Mixer レシピ追加

引数は　生成物, 生成液体, 搬入物配列, 搬入液体, クラフト時間(tick), エネルギー量/tick
*/
//砂とバラの低木と水1000mBでFertilizerとWater Mixed Red Dyeを作成, 100tick, 16EU/tick, 計1600EU
mods.gregtech.Mixer.addRecipe(<IC2:itemFertilizer>,
<liquid:dye.watermixed.dyered> * 1000, 
[<minecraft:sand>, <minecraft:double_plant:4>], 
<liquid:water> * 1000,
100, 16);

/*
Oil Cracker レシピ追加

引数は　回路番号, 生成物, 搬入液体1, 搬入液体2, クラフト時間(tick), エネルギー量/tick
*/
//Programming Circuit ==1, Milk 1000mB, 溶岩 500mBから水200mBを作成, 30tick, 1200EU/tick, 計36000EU
mods.gregtech.OilCracker.addRecipe(1,
<liquid:water> * 200,
<liquid:lava> * 500, <liquid:milk> * 1000,
30, 1200);

/*
Ore Washer レシピ追加

引数は　生成物1, 生成物2, 生成物3, 搬入物, クラフト時間(tick), エネルギー量/tick

↓はエラーが出る？
生成物1, 生成物2, 生成物3, 搬入物, 搬入液体, クラフト時間(tick), エネルギー量/tick
*/
//土と水1000mBから木と砂とStone Dustを生成
mods.gregtech.OreWasher.addRecipe(<minecraft:planks>, <minecraft:sand>,  <gregtech:gt.metaitem.01:2299>,
<minecraft:dirt>,
300, 2);

/*
Packer レシピ追加

引数は　生成物, 搬入物1, 搬入物2, クラフト時間(tick), エネルギー量/tick

個数を*0にすることで消滅しない
*/
//鉄インゴット9個とSchematic(3×3)で、鉄ブロック作成, 25EU/t, 50tick, 1250EU
mods.gregtech.Packer.addRecipe(<minecraft:iron_block>,
<minecraft:iron_ingot> * 9, <gregtech:gt.metaitem.01:32497> * 0,
50, 25);

/*
Plasma Arc Furnaceレシピ追加

引数は　生成物配列, 生成液体, 搬入物, 搬入液体, 生成物生成確立(÷100したものが%), クラフト時間(tick), エネルギー量/tick
*/
//IC2のSteam CellとNitrogen Plasma 250mBから、IC2のSuperheated Steam Cell(100%)とNitrogen 250mBを生成, 65tick, 30EU/tick, 計1950EU
mods.gregtech.PlasmaArcFurnace.addRecipe([<IC2:itemCellEmpty:13>], 
<liquid:nitrogen> * 250,
<IC2:itemCellEmpty:14>, 
<liquid:plasma.nitrogen> * 250, 
[10000],
65, 30);

/*
Bending Machineレシピ追加

引数は　生成物, 搬入物, クラフト時間(tick), エネルギー量/tick

Programmed Circuitが自動追加、番号は搬入物の数
*/
//GT5UのObsidian Plate9枚とProgrammed Circuit ==9でIC2のDense Obsidian Plate作成, 3600tick, 96EU
mods.gregtech.PlateBender.addRecipe(<IC2:itemDensePlates:7>,
<gregtech:gt.metaitem.01:17804> * 9,
3600, 96);

/*
Polarizerレシピ追加

引数は　生成物, 搬入物, クラフト時間(tick), エネルギー量/tick
*/
//鉄ブーツからIC2のStatic Boots作成, 600tick, 30EU/tick, 18000EU
mods.gregtech.Polarizer.addRecipe(<IC2:itemStaticBoots>,
<minecraft:iron_boots>,
600, 30);

/*
Precision Laser Engraverレシピ追加

引数は　生成物, レンズ, 搬入物, クラフト時間(tick), エネルギー量/tick

個数を*0にすることで消滅しない
*/
//ダイアモンド4個とDiamond LensからFlawless Diamondを作成, 1200tick, 480EU/tick, 576000EU
mods.gregtech.PrecisionLaser.addRecipe(<gregtech:gt.metaitem.02:29500>, <gregtech:gt.metaitem.01:24500> * 0,
<minecraft:diamond> * 4,
1200, 480);

/*
Primitive Blast Furnaceレシピ追加

引数は　生成物1, 生成物2, 搬入物1, 搬入物2, クラフト時間(tick), エネルギー量/tick
*/
//ダイアモンドと土と石炭32個から、石と砂利とAshesを作成、1200tick
mods.gregtech.PrimitiveBlastFurnace.addRecipe(<minecraft:stone>, <minecraft:gravel>,
<minecraft:diamond>, <minecraft:dirt>,
1200, 32);

/*
Printerレシピ追加

引数は　生成物, 搬入物, 搬入Data Stick(以外でも可), 搬入液体, クラフト時間(tick), エネルギー量/tick
*/
//鉄の剣とエンチャント瓶6個とSquid Ink 1mBから、ダメージ増加Ⅰの鉄の剣を作成、32tick, 100EU/tick, 3200EU
mods.gregtech.Printer.addRecipe(<minecraft:iron_sword>.withTag({ench: [{lvl: 1 as short, id: 16 as short}]}),
<minecraft:iron_sword>,
<minecraft:experience_bottle> * 6,
<liquid:squidink>,
32, 100);

/*
Pulveriserレシピ追加

引数は　生成物配列, 搬入物, 生成物生成確立配列(÷100したものが%), クラフト時間(tick), エネルギー量/tick
*/
//ポドゾルから、土とPlantball(30%)ときのこ(15%)と茶きのこ(15%)を生成、400tick, 2EU/tick, 800EU
mods.gregtech.Pulverizer.addRecipe([<minecraft:dirt>, <IC2:itemFuelPlantBall>, <minecraft:red_mushroom>, <minecraft:brown_mushroom>], <minecraft:dirt:2>, [10000, 3000, 1500, 1500], 400, 2);

/*
Pyrolyse Ovenレシピ追加

引数は　生成物, 生成液体, 回路番号, 搬入物, 搬入液体, クラフト時間(tick), エネルギー量/tick
*/
//木とProgrammed Circuit ==1から石炭64個と水1000mB生成
mods.gregtech.PyrolyseOven.addRecipe(<minecraft:coal>*64,
<liquid:water>*1000,
1,
<minecraft:planks>,
null,
40, 1200);
 
/*
Electromagnetic Separatorレシピ追加

引数は　生成物配列, 搬入物, 生成物生成確立配列(÷100したものが%), クラフト時間(tick), エネルギー量/tick
*/
//Nether Star DustからChipped Diamond(50%), Small Pile of Naquadah Dust(20%), Tiny Pile of Naquadah Dust(15%)を作成, 200tick, 300EU/tick, 60000EU
mods.gregtech.Separator.addRecipe([<gregtech:gt.metaitem.02:27500>, <gregtech:gt.metaitem.01:1324> * 2, <gregtech:gt.metaitem.01:324> * 4], 
<gregtech:gt.metaitem.01:2506>,
[5000, 2000, 1500],
200, 300);

/*
Sifterレシピ追加

引数は　生成物配列, 搬入物, 生成物生成確立配列(÷100したものが%), クラフト時間(tick), エネルギー量/tick
*/
//土から、種(20%)とStone Dust(5%)とFertilizer(2.5%)を生成, 10tick, 5EU/tick, 50EU
mods.gregtech.Sifter.addRecipe([<minecraft:wheat_seeds>, <gregtech:gt.metaitem.01:2299>, <IC2:itemFertilizer>],
<minecraft:dirt>,
[2000, 500, 250],
10, 5);

/*
Slicerレシピ追加

引数は　生成物, 搬入物, 搬入Blade, クラフト時間(tick), エネルギー量/tick

個数を*0にすることで消滅しない
*/
//スイカブロックとSlicer Blade(Flat)から、スイカ8個作成, 100tick, 8EU/tick, 800EU
mods.gregtech.Slicer.addRecipe(<minecraft:melon> * 8, 
<minecraft:melon_block>,
<gregtech:gt.metaitem.01:32398> * 0,
100, 8);

/*
Thermal Centrifugeレシピ追加

引数は　生成物1, 生成物2, 生成物3, 搬入物, クラフト時間(tick), エネルギー量/tick
*/
//丸石から、土、砂、石を生成、200tick, 120EU/tick, 24000EU
mods.gregtech.ThermalCentrifuge.addRecipe(<minecraft:dirt>, <minecraft:sand>, <minecraft:stone>,
<minecraft:cobblestone>,
200, 120);

/*
Unpackerレシピ追加

引数は　生成物1, 生成物2, 搬入物, クラフト時間(tick), エネルギー量/tick
*/
//TNTから、砂4個と火薬5個を生成, 50tick, 200EU/tick, 10000EU
mods.gregtech.Unpacker.addRecipe(<minecraft:sand> * 4, <minecraft:gunpowder> * 5,
<minecraft:tnt>,
50, 200);

/*
Vacuum Freezerレシピ追加

引数は　生成物, 搬入物, クラフト時間(tick)

消費電力は変更不可？
*/
//IC2のPahoehoe Lava Cellから、IC2Lava Cell生成, 50tick, 120EU/tick, 6000EU
mods.gregtech.VacuumFreezer.addRecipe(<IC2:itemCellEmpty:2>,
<IC2:itemCellEmpty:11>,
50);

/*
Wiremillレシピ追加

引数は　生成物, 搬入物, クラフト時間(tick), エネルギー量/tick
*/
//羊毛から、糸4つ作成, 100tick, 50EU/tick, 5000EU
mods.gregtech.Wiremill.addRecipe(<minecraft:string> * 4,
<minecraft:wool>,
100, 50);

Gregtech6 連携

  • MTUtilsの導入必須
  • 最新版のレシピキーはソースコード参照
  • 液体は、液体リストか/mt liquidsで取得
    • /*
レシピキー　一覧

Furnace
mc.recipe.furnace

Microwave
gt.recipe.microwave

Bedrock Drill
gt.recipe.bedrockorelist

Ore Byproduct List
gt.recipe.byproductlist

Crucible Smelting
gt.recipe.cruciblesmelting

Combination Smelting
gt.recipe.cruciblealloying

Bumblebee Queen
gt.recipe.bumblequeen

Family Tree
gt.recipe.trees

Generifier
gt.recipe.generifier

Boxinator
gt.recipe.boxinator

Unboxinator
gt.recipe.unboxinator

Sharpener
gt.recipe.sharpener

Sifter
gt.recipe.sifter

Anvil
gt.recipe.anvil

Anvil Bending (Small)
gt.recipe.anvil.bend.small

Anvil Bending (Big)
gt.recipe.anvil.bend.big

Hammer
gt.recipe.hammer

Chisel
gt.recipe.chisel

Shredder
gt.recipe.shredder

Crusher
gt.recipe.crusher

Lathe
gt.recipe.lathe

Cutter
gt.recipe.cutter

Debarker
gt.recipe.debarker

Coagulator
gt.recipe.coagulator

Squeezer
gt.recipe.squeezer

Juicer
gt.recipe.juicer

Mortar
gt.recipe.mortar

Compressor
gt.recipe.compressor

Centrifuge
gt.recipe.centrifuge

Electrolyzer
gt.recipe.electrolyzer

Lightning Processor
gt.recipe.lightning

Implosion Compressor
gt.recipe.implosioncompressor

Rolling Mill
gt.recipe.rollingmill

Roll Bender
gt.recipe.rollbender

Roll Former
gt.recipe.rollformer

Cluster Mill
gt.recipe.clustermill

Wiremill
gt.recipe.wiremill

Mixer
gt.recipe.mixer

Burner Mixer
gt.recipe.burnmixer

Cryo Mixer
gt.recipe.cryomixer

Freezer
gt.recipe.freezer

Canning Machine
gt.recipe.canner

Injector
gt.recipe.injector

Calciner
gt.recipe.calciner

Roaster
gt.recipe.roaster

Dryer
gt.recipe.drying

Fermenter
gt.recipe.fermenter

Distillery
gt.recipe.distillery

Extruder
gt.recipe.extruder

Polarizer
gt.recipe.polarizer

Loom
gt.recipe.loom

Cooker
gt.recipe.cooker

Press
gt.recipe.press

Bath
gt.recipe.bath

Smelter
gt.recipe.smelter

Precision Laser Engraver
gt.recipe.laserengraver

Welding Machine
gt.recipe.welder

Crystallisation Crucible
gt.recipe.crystallisationcrucible

Plantalyzer
gt.recipe.plantalyzer

Bumblelyzer
gt.recipe.bumblelyzer

Scanner (Visuals)
gt.recipe.scannervisuals

Printer
gt.recipe.printer

Sluice
gt.recipe.sluice

Magnetic Separator
gt.recipe.magneticseparator

Crafting
gt.recipe.autocrafting

Nanoscale Fabricator
gt.recipe.nanofab

Matter Fabricator
gt.recipe.massfab

Molecular Scanner
gt.recipe.scannermolecular

Matter Replicator
gt.recipe.replicator

Slicer
gt.recipe.slicer

Laminator
gt.recipe.laminator

Coke Oven
gt.recipe.cokeoven

Distillation Tower
gt.recipe.distillationtower

Steam Cracking
gt.recipe.steamcracking

Catalytic Cracking
gt.recipe.catalyticcracking

Autoclave
gt.recipe.autoclave

Fusion Reactor
gt.recipe.fusionreactor

Blast Furnace
gt.recipe.blastfurnace

Vacuum Freezer
gt.recipe.vacuumfreezer

Assembler
gt.recipe.assembler

CNC Machine
gt.recipe.cncmachine
/*

/*
レシピ追加方法

MTUtilsGT.addCustomRecipe("レシピキー",
真偽値(効果不明),
EU/tick,
tick,
[生成物生成確立配列(÷100したものが%)],
[搬入物配列],
[搬入液体配列],
[生成液体配列],
[生成物配列]);
*/
//Nanoscale Fabricatorにて、Adamantium IngotとGaia Spirit IngotとCharged Matter 1000mBから、エンドポータルを作成, 8192GU/tick, 2400tick, 計19660800GU
MTUtilsGT.addCustomRecipe("gt.recipe.nanofab",
true,
8192,
2400,
[10000],
[<gregtech:gt.meta.ingot:2220>, <Botania:manaResource:14>],
[<liquid:chargedmatter>*1000],
null,
[<minecraft:end_portal_frame>]);

/*
レシピ削除方法

特定の機械の、特定の生成物を作るレシピをすべて削除
MTUtilsGT.removeAllRecipes("レシピキー", 生成物);

特定の機械の、特定のレシピのみ削除
MTUtilsGT.removeRecipe("レシピキー",
レシピ変更フラグ(基本true?),
EU/tick,
tick,
[生成物生成確立配列(÷100したものが%)],
[搬入物配列],
[搬入液体配列],
[生成液体配列],
[生成物配列]);
*/
//エンドポータル削除1
MTUtilsGT.removeAllRecipes("gt.recipe.nanofab", <minecraft:end_portal_frame>]);

//エンドポータル削除2
MTUtilsGT.removeRecipe("gt.recipe.nanofab",
true,
8192,
2400,
[10000],
[<gregtech:gt.meta.ingot:2220>, <Botania:manaResource:14>],
[<liquid:chargedmatter>*1000],
null,
[<minecraft:end_portal_frame>]);

Industrial Craft2(IC2exp)連携

  • .jarファイル内の ./assets/ic2/config/ 内の .iniファイル を、(modpack)/config/にぶち込み編集することで、レシピ変更や削除が可能
    • //IC2の電化アイテムによるクラフト
//どのダメージでもよいChainsaw
val chainsaw = <IC2:itemToolChainsaw>.anyDamage();
//100EU以上のChainsawのみクラフト可能(onlyIC2ChargeAtLeast)、クラフト後100EU減少(transformIC2Discharge)
recipes.addShapeless(<minecraft:stick> * 3,
[<ore:plankWood>, chainsaw.onlyIC2ChargeAtLeast(100).transformIC2Discharge(100)]);

/*
各種機械のレシピ変更
*/
import mods.ic2.Canner;
import mods.ic2.Compressor;
import mods.ic2.Extractor;
import mods.ic2.Macerator;
import mods.ic2.MetalFormer;
import mods.ic2.OreWasher;
import mods.ic2.ThermalCentrifuge;

//Compressorレシピ追加
//棒から木を作る
Compressor.addRecipe(<minecraft:planks>, <minecraft:stick>);

//Extractorレシピ追加
//パンから小麦を作成
Extractor.addRecipe(<minecraft:wheat>, <minecraft:bread>);

//Maceratorレシピ追加
//パンから小麦2個作成
Macerator.addRecipe(<minecraft:wheat> * 2, <minecraft:bread>);

//MetalFormer(Cuttingモード)レシピ追加
//木から棒3本作成
MetalFormer.addCuttingRecipe(<minecraft:stick> * 3, <minecraft:planks:*>);

//MetalFormer(Extrudingモード)レシピ追加
//木から棒3本作成
MetalFormer.addExtrudingRecipe(<minecraft:stick> * 3, <minecraft:planks:*>);

//MetalFormer(Rollingモード)レシピ追加
//木から棒3本作成
MetalFormer.addRollingRecipe(<minecraft:stick> * 3, <minecraft:planks:*>);

//Ore Washing Plantレシピ追加
//パンと水1000mBから、小麦と種を作成
OreWasher.addRecipe([<minecraft:wheat>, <minecraft:wheat_seeds>],
<minecraft:bread>,
1000);

//Thermal Centrifugeレシピ追加
//パンと1000Heatから、小麦と種を作成
ThermalCentrifuge.addRecipe([<minecraft:wheat>, <minecraft:wheat_seeds>],
<minecraft:bread>,
1000);

//Cannerレシピ追加

//Blast Furnaceレシピ追加

//Fluid Heat Generatorレシピ追加

//Matter Amplifierレシピ追加

//Recyclerレシピ追加

//ScrapBoxレシピ追加

//Semi Fluid Generatorレシピ追加

Magneticraft連携

MineFactory Reloaded連携

NEI連携

Tinkers' Steelworks連携

Witching Gadgets連携

Applied Energistics 2連携

Aura Cascade連携

Botania連携

Chisel 2連携

Ex Nihilo連携

Extra Utilities連携

Factorization連携

Forestry連携

Mariculture連携

Mekanism連携

Metallurgy 4連携

PneumaticCraft連携

Railcraft連携

Thaumcraft 4連携

Thermal Expansion連携

Tinker's Construct連携